Sub Regex_Przyklad_1()

'Sprawdzanie poprawności adresu mailowego
Dim oRegex As Object
Dim strText As String

Set oRegex = CreateObject("VBScript.Regexp")
strText = "admin@vbamania.pl"

'wzorzec e-maila
oRegex.Pattern = "[a-z0-9_.-]+@[a-z0-9_.-]+\.\w{2,4}"

If oRegex.Test(strText) Then MsgBox "Adres prawidłowy - " & strText Else MsgBox "Adres nieprawidłowy - " & strText

Set oRegex = Nothing

End Sub

Sub Regex_Przyklad_2()

'wyłuskiwanie liczb z tekstu
Dim oRegex As Object, oMatches As Object, oM As Object
Dim strText As String, strKom As String, strP As String

Set oRegex = CreateObject("VBScript.Regexp")
strText = "Wyplata: 3500 PLN, ZUS: 1018 PLN, II filar: 190 PLN, III filar: 25 PLN"

'tylko 4-cyfrowe liczby
oRegex.Pattern = "(^|\D)\d{4}(\D|$)"
'liczba cyfr od 2 do 3
'oRegex.Pattern = "(^|\D)\d{2,3}(\D|$)"

'wyszukuje wszystkie ciągi znaków spełniające warunek
oRegex.Global = True

'wyszukuje tylko pierwszy ciąg znaków spełniający warunek
'oRegex.Global = false

Set oMatches = oRegex.Execute(strText)

If oMatches.Count > 0 Then
    For Each oM In oMatches
        If oM Is oMatches(oMatches.Count - 1) Then strP = "" Else strP = ", "
        strKom = strKom & oM.Value & strP
    Next oM
    strKom = "Dopasowania: " & strKom
Else
    strKom = "Brak dopasowań"
End If

MsgBox strKom

Set oRegex = Nothing
Set oMatches = Nothing

End Sub

Sub Regex_Przyklad_3()

'Zamiana jednego ciągu na inny
Dim oRegex As Object
Dim strText As String, strNewText As String
Dim dblWynik As Double

Set oRegex = CreateObject("VBScript.Regexp")
strText = "Wynik wynosi: %d" & vbCrLf & _
          "Result is: %d"

'wyszukuje wszystkie ciągi znaków spełniające warunek
oRegex.Global = True

'wyszukuje tylko pierwszy ciąg znaków spełniający warunek
'oRegex.Global = False

'wzorzec
oRegex.Pattern = "%d"
dblWynik = 10.244

strNewText = oRegex.Replace(strText, dblWynik)

MsgBox strNewText

Set oRegex = Nothing

End Sub

Private Sub UserForm_Activate()

Me.ListView1.SmallIcons = Me.ImageList1

Dim oLi As ListItem
Set oLi = Me.ListView1.ListItems.Add(, , "Kolumna nr 1", , "icon1")
oLi.ListSubItems.Add , , "Kolumna nr 2", "icon2"

Set oLi = Nothing

End Sub